Введение

Протоколу MIDI (Musical Instrument Digital Interface, дигитальный интерфейс для музыкальных инструментов) в 2013 году исполняется 30 лет. Однако он настолько хорошо удовлетворяет потребности музыкантов и музыкальных инженеров, что вряд ли в ближайшее время он будет вытеснен каким-либо другим стандартом.

Статья организована так: сперва я расскажу, как можно подключить два MIDI-устройства друг к другу (рассмотрим вариант ATtiny2313 и ПК), затем в двух словах опишу основные используемые в стандарте команды, и, наконец, покажу как можно ранее разработанное устройство подружить с MIDI.

Связь с ПК посредством MIDI

Строго говоря, для использования MIDI протокола желательно соответствующее оборудование. Например, аудио-карта, оснащённая MIDI-интерфейсом (здесь до сих пор используется популярный некогда DIN5), или специальное USB-устройство. Это не всегда под рукой, а использовать MIDI всё-таки хочется. Тут можно вспомнить про некий стандарт RS-232 и поискать на заднице компьютера COM-порт. У меня на ноутбуке конечно ничего такого не найдёшь, но сгодится и USB-COM конвертер.

О подключении ATtiny2313 к RS-232-совместимому интерфейсу можно писать отдельную статью, но это не входит в мои цели. Напоминаю, что USART-устройство ATtiny2313 выдаёт TTL-уровни (0/5В), а RS-232 хочет -12/+12В в качестве обозначения логических состояний. Поэтому чтобы связать tiny с COM-портом можно использовать либо специальную микросхему (MAX232), либо более дешёвый и простой способ, тут уж смотря какие конечные цели^[1].

Общая схема подключения выглядит следующим образом:

Конечно, без определённых ухищрений музыкальные программы напрямую работать с COM-портом не будут. А поэтому надо как-то наладить коммуникацию. На выручку приходит драйвер от компании Roland, подходящий для произвольного устройства и создающий в системе виртуальный MIDI-порт, присылающий и принимающий сообщения от COM-порта (своеобразный мост). Скачать можно на официальном сайте, например для Windows XP можно забрать отсюда, там же на сайте есть подходящий драйвер и для MacOS.

Во время установки надо проследить, чтобы был выбран правильный идентификатор COM-порта. У меня, например, это COM1. Кстати, драйвер от Roland хочет обязательно работать с портами в диапазоне COM1…4, так что в случае назначения системой физическому порту номера 5 и выше, нужно будет изменить эту настройку. Если у вас Windows XP, то порты можно проверить в диспетчере устройств. Если всё правильно настроено, в системе появится дополнительный MIDI порт: входы Roland Serial MIDI Input и два выхода Roland Serial MIDI Out A и B. Согласно этому настраиваем и любую программу, принимающую/отправляющую MIDI-сообщения через COM-порт.

Внимание! Теперь ваш COM-порт будет занят MIDI-приложениями, и для доступа к нему нужно закрыть MIDI-соединения.

Краткое описание MIDI-протокола

Для передачи информации посредством MIDI используется асинхронный последовательный протокол, для пересылки байта нужно 10 бит: стартовый бит, 8 бит информации и стоп-бит. Скорость передачи по стандарту равна 31.25 кбод. Как видно, USART-компонент ATtiny2313 идеально подходит для физической реализации протокола.

Формат сообщений

Вообще говоря, сообщение может состоять как из одного, так и из нескольких байт. Однако первый байт всегда является идентификатором команды (статусный байт):

Старший полубайт (биты 7…4) задают команду, а младший полубайт (биты 3…0) — MIDI-канал, к которому относится команда.

Мы с вами рассмотрим далее сообщения, состоящие из 3 байт информации (статусный байт и два байта данных). Этого вполне достаточно для упрощённой реализации протокола. Полубайты команд буду задавать в шестнадцатиричном представлении. Таким образом, рассматриваемые сообщения выглядят так:

Поговорим теперь по порядку об интересующих нас MIDI-сообщениях.

Note On сообщение — 0X9

Данная команда используется для «включения», то есть начала проигрывания ноты на заданном канале. Она имеет вид 0X9K 0XNN 0XVV, где K — номер канала (0X0…0XF, то есть от 1 до 16), NN — номер ноты (0X00…0X7F; 0…127), VV — так называемая скорость (velocity) извлечения ноты (0X00…0X7F; 0…127), что соответствует динамике исполнения.

Приведу пример. Допустим на инструмент поступило сообщение 0X91 0X45 0X60. Это значит, что инструмент должен начать воспроизведение ноты под номером 0X45, что есть нота ля первой октавы (440 Гц) с динамикой 0X60 на втором канале.

Note Off сообщение — 0X8

Эта команда выполняет прямо противоположное действие предыдущей, выключая ноту на заданном канале, при этом её формат 0X8K 0XNN 0XVV. Поскольку динамика «выключения» учитывается редко, то содержание VV обычно 0X00.

Рассматривая предыдущий пример: для выключения ноты ля первой октавы на втором канале можно отправить сообщение 0X81 0X45 0X00.

Тут есть одно важное замечание. Дело в том, что спецификация MIDI позволяет заменять сообщения Note Off сообщениями Note On с нулевой динамикой.

Так что выключить ноту в нашем примере можно и при помощи сообщения 0X91 0X45 0X00. Это важно помнить при программировании MIDI-устройств.

Controller Change (CC) сообщение — 0XB

Сообщения изменения контроллеров используются для изменения таких параметров исполнения, как, например, громкость. Формат следующий: 0XBK 0xNN 0xVV, где K — номер канала, на котором необходимо изменить параметры контроллера, NN — номер контроллера (0X00…0X7F), VV — значение настройки контроллера (0X00…0X7F).

Нас здесь может заинтересовать сообщение контроллера 0XBK 0x7B 0x00 — «All Notes Off», которое используется для одновременного отключения всех нот на заданном канале K.

Схема устройства

Схема практически не изменилась, разве что добавился коннектор для подключения конвертера уровней, оговоренного выше^[2].

Программный код

Перейдём теперь к программированию микроконтроллера. Рассмотрим случай управления двухголосым синтезатором при помощи MIDI. Сначала, как обычно, «шапка» прошивки.

 ; Проект для ATtiny2313
; Управляемый MIDI Двухголосый Орган v1

.INCLUDE "tn2313def.inc"

.DEF	Velocity	= R8

.DEF	SrSave		= R9

.DEF	Tone1H	= R10
.DEF	Tone1L	= R11
.DEF	Tone2H	= R12
.DEF	Tone2L	= R13

.DEF	ToneTH	= R14
.DEF	ToneTL	= R15

.DEF	ReadBufferL = R16
.DEF	ReadBufferH	= R17

.DEF	Temp	= R18

.DEF	Temp1 	= R19
.DEF	Temp2	= R20
.DEF	Temp3	= R21
.DEF 	Temp4	= R22

.DEF	ADDRH	= R23
.DEF 	ADDRL	= R24

.DEF	RxByte  = R25
.DEF	ByteCnt	= R26

.MACRO OUTI
	ldi R16,@1
	out @0,R16
.ENDM

.MACRO ADI
	subi @0, -@1
.ENDM

.MACRO MEMR
	lds @0, @1
.ENDM

.MACRO MEMW
	sts @0, @1
.ENDM

.MACRO MEMWI
	ldi R16, @1
	sts @0, R16
.ENDM	

.EQU BUFFERSIZE 	= 3		; Размер буфера приёмника
.EQU VOICENUM		= 2		; Число доступных голосов

; ---------
; Константы
; ---------

; MIDI протокол

; Используем MIDI канал 1 ---

; Note on
.EQU NoteOn 	= 0x90

; Note off
.EQU NoteOff 	= 0x80

; Controller change
.EQU ControllerChange = 0xB0

; Контроллеры
.EQU AllNotesOff = 0x7B

; ---------------------------

; Самая низкая MIDI-нота (C2 = 36)
.EQU LowNote = 36

; Порты

.EQU Voice1 = PB3
.EQU Voice2 = PB4
.EQU LED	= PB0

; --------------
; Разметрка SRAM
; --------------
.DSEG

notebuffer:
	.BYTE BUFFERSIZE

voices:
	.BYTE VOICENUM

; ----------------
; Начало программы
; ----------------
.CSEG
.ORG 0x0000

RJMP RESET ; Reset Handler
RETI ;RJMP INT0 ; External Interrupt0 Handler
RETI ;RJMP INT1 ; External Interrupt1 Handler
RETI ;RJMP TIM1_CAPT ; Timer1 Capture Handler
RJMP TIMER1_COMPA ; Timer1 CompareA Handler
RETI ;RJMP TIM1_OVF ; Timer1 Overflow Handler
RETI ;RJMP TIM0_OVF ; Timer0 Overflow Handler
RJMP USART0_RXC ; USART0 RX Complete Handler
RETI ;RJMP USART0_DRE ; USART0,UDR Empty Handler
RETI ;RJMP USART0_TXC ; USART0 TX Complete Handler
RETI ;RJMP ANA_COMP ; Analog Comparator Handler
RETI ;RJMP PCINT ; Pin Change Interrupt
RJMP TIMER1_COMPB ; Timer1 Compare B Handler
RETI ;RJMP TIMER0_COMPA ; Timer0 Compare A Handler
RETI ;RJMP TIMER0_COMPB ; Timer0 Compare B Handler
RETI ;RJMP USI_START ; USI Start Handler
RETI ;RJMP USI_OVERFLOW ; USI Overflow Handler
RETI ;RJMP EE_READY ; EEPROM Ready Handler
RETI ;RJMP WDT_OVERFLOW ; Watchdog Overflow Handler

Здесь, пожалуй, отдельных комментариев не требуется. Стандартные макросы, которые хорошо бы выносить для удобства в отдельный файл, и константы. Буфер USART-приёмника составляет 3 байта, ровно столько, сколько нужно для приёма 3-байтовых сообщений NoteOn, NoteOff и ControllerChange, то есть это полностью удовлетворяет упрощённой реализации протокола.

Следом за шапкой идёт стандартная инициализация периферии — это описывать не буду, посмотрите это в полном коде^[3]. Реализация двухголосого синтезатора также не изменилась. А вот на приёме сообщений и их обработке остановимся более подробно.

Приём MIDI-сообщений

За приём любых сообщений по USART отвечает прерывание USART0_RXC. Оттуда и посмотрим:

 ; USART receive byte
USART0_RXC:

	; Отключить прерывания
	cli

	in SrSave, SREG

	; Загрузить байт из регистра
	in RxByte, UDR

	; Записать байт в буффер
	ldi YL, low(notebuffer)
	ldi YH, high(notebuffer)

	; Сместив позицию на число в счётчике
	clr temp
	add YL, ByteCnt
	adc YH, temp

	st Y, RxByte

	; Проверить счётчик байтов
	cpi ByteCnt, 0
	breq checkNoteOnOffMessage

	cpi ByteCnt, 2
	breq handleMidiNote

	rjmp incCounter

checkNoteOnOffMessage:

	; Проверить тип сообщения и
	; пропустить только NoteOn, NoteOff, CC
	cpi RxByte, NoteOn
	breq incCounter

	cpi RxByte, NoteOff
	breq incCounter

	cpi RxByte, ControllerChange
	breq incCounter

DiscardByte:

	; Отменить сообщение, сбросить счётчик
	clr ByteCnt
	rjmp getOutNoteCheck

incCounter:

	inc ByteCnt

getOutNoteCheck:

	; Выйти из процедуры
	out SREG, SrSave

	sei
	reti

Что же здесь происходит? Байты, прилетающие по USART записываются в память по указателю парного регистра Y, со смещением, указанным в счётчике. Таким образом в память приходит MIDI-сообщение. Но только в том случае, если оно соответствует фильтру: пропускаются только сообщения NoteOn, NoteOff и относящиеся к изменению контроллеров через команду ControllerChange. Всё остальное откидывается, счётчик обнуляется и ожидается правильная команда. Как только счётчик указывает на поступление третьего байта, управление передаётся процедуре handleMidiNote, о которой поговорим далее.

Обработка команд

Процедура обработки сообщений выглядит так:

handleMidiNote:

	; Читаем из памяти: temp - действие, temp1 - нота
	memr temp, notebuffer
	memr temp1, notebuffer+1

	mov temp2, temp1		; Сохраним temp1 для CC

    memr velocity, notebuffer+2	; Сохраним также динамику

	subi temp1, LowNote		; Найти правильный номер ноты
	inc temp1

	; Выбрать правильное действие относительно команды
	cpi temp, NoteOn
	breq doNoteOn

	cpi temp, NoteOff
	breq doNoteOff

	cpi temp, ControllerChange
	breq doControllerChange

doNoteOn:

	; Проверить на нулевую скорость нажатия (динамику)
	clr temp2
	cp velocity, temp2
	breq doNoteOff			; Тогда нужно NoteOff

	; Далее включим ноту

	; Проверяем первый голос
	memr temp2, voices
	cpi temp2, 0
	brne NotFree1

	; Если свободен, ставим ноту сюда
	memw voices, temp1
	rcall setCh1

DoneNoteOnOff:
	; Всё сделано, очищаем счётчик
	clr ByteCnt
	rjmp getOutNoteCheck

NotFree1:

	; Проверим, свободен ли этот голос
	memr temp2, voices+1
	cpi temp2, 0
	brne DoneNoteOnOff	; Нет, нота не будет исполнена

	memw voices+1, temp1
	rcall setCh2

	rjmp DoneNoteOnOff

doNoteOff:

	; Проверим первый голос
	memr temp2, voices
	cp temp1, temp2
	brne notOnCh1

	; Нота найдена, освобождаем первый голос
	clr temp1
	rcall setCh1
	memwi voices, 0
	rjmp DoneNoteOnOff

notOnCh1:

	; Проверим второй голос
	memr temp2, voices+1
	cp temp1, temp2
	brne DoneNoteOnOff	 ; Нота нигде не найдена, выход

	; Нота занимает второй голос, очищаем
	clr temp1
	rcall setCh2
	memwi voices+1, 0
	rjmp DoneNoteOnOff

doControllerChange:

	; Проверим temp2 на "All notes off" сообщение
	cpi temp2, AllNotesOff
	brne DoneNoteOnOff

	; Такое сообщение поступило, очищаем оба канала
	memwi voices, 0
	memwi voices+1, 0

	cbi DDRB, voice1
	cbi DDRB, voice2

	rjmp DoneNoteOnOff

Здесь вся логика действий обусловлена условными переходами. В случае включения ноты — ищется свободный канал, и если он найден, то нота записывается туда и включается воспроизведение (иначе нота игнорируется). При нулевой динамике происходит переход к обработке NoteOff, равно как и при поступлении соответствующего сообщения. Там отключаемая нота ищется сначала на первом голосе, потом и на втором, если она найдена, то отключается — иначе игнорируется. Единственное воспринимаемое CC-сообщение — All Notes Off, отключить все ноты. При его поступлении вне зависимости от содержания голосов они очищаются и воспроизведение немедленно прекращается.

Полный код программы

А вот и полный код (комментарии на английском):
ATTiny2313MIDIMusicPlayer_BlogVersion.asm

Результат

Далее можно посмотреть, как ATtiny2313 исполняет 3-ую часть «Лунной сонаты» Бетховена (для воспроизведения используется программа Guitar Pro 5):

Заключение

Надеюсь, статья была полезной! На пути следующие статьи, посвящённые MIDI и DDS (Direct Digital Synthesis). 2 канала по 4 голоса, независимо воспроизводящие синусоидальные, треугольные, пилообразные, прямоугольные сигналы при помощи этой же платы? Переделка старого синтезатора в MIDI-клавиатуру с возможностью выбора динамики? Всё это на старом знакомом ATtiny2313? Да, это есть у нас :-) Если что-то из этого особенно интересно, пишите в комментариях.

Примечания

Использованные материалы

1. http://www.gweep.net/~prefect/eng/reference/protocol/midispec.html
2. http://www.phys.unsw.edu.au/jw/notes.html
3. http://www.midi.org/techspecs/midimessages.php

Введение

В сложных электронных проектах, требующих ввода пользовательских данных, часто выгодно использовать компьютерную клавиатуру. В зависимости от микроконтроллера, у него может быть встроенная поддержка как PS/2, так и USB HID стандартов. У ATtiny2313 этого добра нет, но подключить к нему клавиатуру и организовать её правильную работу довольно просто. Об этом и пойдёт речь в статье^[1].

Схема устройства

Схема осталась прежней. Что нужно добавить: переходник от прошивочного шлейфа к клавиатуре. Распиновки для стандартного PS/2 коннектора, а также для DIN5 (встречается на старых клавиатурах):

PS/2: 1. KBD Clock (часы) 2. GND 3. KBD Data (данные) 4. N/C 5. +5V 6. N/C

DIN5: 1. KBD Clock 2. KBD Data 3. N/C 4. GND 5. +5V (VCC)

Соответствие выводам микроконтроллера^[2] следующее:

• PB5 → KBD Clock
• PB6 → KBD Data

Как видно, используется всего 2 контакта — синхролиния (часы) и линия данных. Кроме этого клавиатура отжимает +5В питания с платы микроконтроллера.

Принципы работы клавиатуры

При подключении клавиатуры стандарта AT сначала происходит её инициализация. Если светодиоды-индикаторы работоспособны, то в этот момент они должны синхронно мигнуть. После этого клавиатура готова отсылать и принимать сообщения. Для нашего устройства достаточно одностороннего режима работы — передача сообщений от клавиатуры к хосту.

Передача данных

Для передачи используется простой последовательный протокол. Как было сказано выше, используется два провода. Первый — часы — отвечает за инициирование передачи, определение её направления и регулирование пересылки фрейма. Второй провод несёт непосредственную информацию. Рассмотрим порядок пересылки:

Пересылка фрейма от клавиатуры к хосту

• Сначала уровни на обоих проводах высокие. Это соответствует состоянию ожидания (Idle), то есть ничего не происходит.
• Клавиатура инициирует пересылку, выставив на информационный сигнал в «0» (стартовый бит) и сменив уровень на часах «1»→«0».
• Далее клавиатура пересылает 8 бит данных сообщения от младшего бита к старшему, съем информационного сигнала требуется производить при появлении заднего фронта сигнала часов
• Предпоследний бит называется битом чётности^[3] (parity bit) и используется для проверки целостности переданного байта (простой контроль на ошибку передачи).
• Последний бит равняется «1» и называется стоповым битом.
• Пересылка закончена и линии возвращаются в состояние ожидания.

Как видно, фрейм состоит из 11 бит. Переданный байт же соответствует определённой команде. В простейшем случае это код сканирования (scancode). О них дальше и поговорим.

Коды сканирования

Каждой клавише при нажатии соответствует либо один код, либо комбинация кодов (то есть сообщения состоят из нескольких байт). А когда клавишу отпускаешь, прилетает сообщение из нескольких байт, где первый — 0xF0, а второй (их может быть и несколько) соответствует ранее нажатой клавише. Основные коды приведены на следующем рисунке:

Коды сканирования

Например, если нажать правый ALT, то клавиатура пошлёт сообщение 0xE0 0x11, а если затем отпустить — 0xF0 0xE0 0x11.

На этом теоретическая часть подошла к концу. Посмотрим, как можно реализовать это непосредственно на микроконтроллере.

Программный код

Далее рассмотрим только код, относящийся к снятию сообщений с клавиатуры. В прошлой статье я довольно подробно описывал процедуру создания двухканального синтезатора, и повторяться здесь не буду.

«Шапка» ассемблерного листинга выглядит следующим образом:

 ; Проект для ATtiny2313
.INCLUDE "tn2313def.inc"

; --------------------
; Назначения регистров
; --------------------

.DEF	State	= R8	; Регистр состояния

.DEF	SrSave	= R9	; Регистр для восстановления SR

.DEF	Tone1H	= R10
.DEF	Tone1L	= R11
.DEF	Tone2H	= R12
.DEF	Tone2L	= R13

.DEF	ToneTH	= R14
.DEF	ToneTL	= R15

.DEF	Temp	= R17

.DEF	Temp1 	= R18
.DEF	Temp2	= R19
.DEF	Temp3	= R20
.DEF 	Temp4	= R21

.DEF	ADDRH	= R22
.DEF 	ADDRL	= R23

.DEF	RxByte	= R24
.DEF	BitCnt	= R25

; -------------------------------------------------
; Назначение битов собственного статусного регистра
; -------------------------------------------------

.EQU BitParity = 0
.EQU BitNoteOff = 1

; ------
; Голоса
; ------

.EQU Voice1 = PB3
.EQU Voice2 = PB4

; -----
; МАКРО
; -----

; OUTI порт, значение :: отправить значение в порт
.MACRO OUTI
	ldi R16,@1
	out @0,R16
.ENDM

; MEMR регистр, (место) :: чтение из памяти в регистр
.MACRO MEMR
	lds @0, @1
.ENDM

; MEMW (место), регистр :: записать регистр в память
.MACRO MEMW
	sts @0, @1
.ENDM

; MEMWI (место), значение :: записать значение в память
.MACRO MEMWI
	ldi R16, @1
	sts @0, R16
.ENDM	

; ----
; SRAM
; ----
.DSEG

; Синтезатор на два голоса
voices:

	.BYTE 2

Приём сообщения от клавиатуры

Для приёма данных от клавиатуры нужно инициализировать прерывание по изменению уровня на цифровом входе синхролинии.

Pcint_Init:

	; Включить прерывание по изменению уровня
	outi GIMSK, (1<<PCIE)
	outi PCMSK, (1<<PCINT5)

	ret

В основном цикле программы нужно включить прерывания, а также очистить счётчик битов и статусный регистр. Кроме того, соответствующие изменения надо внести и в вектор прерываний в начале основного кода (добавить rjmp PCINT по соответствующему адресу).

Когда синхролиния свалится в низкий уровень, произойдёт прерывание. Его обработает следующая процедура:

PCINT:

	cli

	in SrSave, SREG
	push SrSave

	; Проверка на задний фронт
	sbis PINB, PB5
	rcall RxKbd

	pop SrSave
	out SREG, SrSave

	sei

	reti

Если обнаружен задний фронт сигнала (момент «1»→«0»), то вызывается процедура RxKbd, которая отвечает за обработку информационного сигнала.

RxKbd:

	; Очистить бит T
	clt

	; Если PB6 установлен, сохранить в T
	sbic PINB, PB6
	set

	; Первый бит фрейма?
	cpi BitCnt, 0
	breq firstBit

	; Проверить чётность
	cpi BitCnt, 9
	breq parityCheck

	; Последний бит фрейма?
	cpi BitCnt, 10
	breq rxFinished

	; Сохранить бит в буфер
	lsr RxByte
	bld RxByte, 7

	; Сохранить бит чётности
	clr Temp1
	bld Temp1, BitParity
	eor State, Temp1

RxBitDone:
	; Инкремент счётчика бит
	inc BitCnt

	ret

firstBit:

	; Очистить буфер
	clr RxByte

	; Очистить бит чётности
	ldi R16, 0xFE
	and State, R16

	rjmp RxBitDone

parityCheck:

	; Сохранить бит чётности
	clr Temp1
	bld Temp1, BitParity
	eor State, Temp1

	rjmp RxBitDone

rxFinished:

	; Проверить бит чётности (нечётность):
	; если = 1, то всё правильно
	sbrs State, BitParity
	rjmp discardByte

	; Очистить счётчик битов
	clr BitCnt

	; Вызвать обработчик байта
	rcall handleByte

	ret

Как это работает:

• При поступлении стартового бита обнуляется буфер и бит чётности.
• Биты 1-8 складываются в буфер, кроме того над ними последовательно производится операция XOR, результат которой сохраняется в бите специального регистра.
• Последняя операция XOR производится с полученным и присланным битами чётности. При этом полученный XOR-ами бит не инвертируется. Следовательно, в результате операции бит чётности должен быть равен 1, если при пересылке не возникло ошибок.
• После получения последнего бита фрейма управление передаётся процедуре discardByte, если проверка чётности провалена, либо в случае успешной передачи процедуре handleByte, которая обработает полученный байт.

Рассмотрим конкретный пример. Допустим пользователь нажимает клавишу ESC, которой соответствует скан-код 0x76. В таком случае произойдёт следующее:

Обработка полученного байта

Поскольку основная статья всё-таки про подключение клавиатуры, я не буду останавливаться подробно на коде обработчика полученного байта, а просто объясню что там к чему.

Нашей задачей было прикрутить к синтезатору клавиатуру. Первая часть задания выполнена, теперь нужно каким-то образом на основе полученных от клавиатуры сообщений включать или выключать воспроизведение определённых нот. Вот как это сделано:

• Синтезатор имеет два голоса.
• При поступлении сообщения о нажатии клавиши ищется свободный голос. Если такой найден — в него отправляется соответствующая клавише нота.
• При поступлении сообщения об отпускании клавиши в статусный регистр заносится метка «следующее сообщение об отпускании клавиши»; когда обрабатывается следующий байт, проверяется, была ли такая клавиша нажата и голос активирован. Если да — соответствующий голос освобождается.
• Если поступает сообщение о нажатии клавиши ESC, оба голоса освобождаются (что-то наподобие Panic Button, если голоса застревают после отпускания клавиш).

Что касается нахождения ноты по клавише, то это сделано по следующей схеме. В памяти кристалла хранится две таблицы. Одна из них уже знакомая таблица нот, где ноты в этот раз заданы в восходящем порядке шагом в полутон. Другая таблица содержит список клавиш, соответствующих этим нотам, также в восходящем порядке. Таким образом, для извлечения ноты необходимо просто найти позицию клавиши во второй таблице и взять ноту на той же позиции из первой. Вот эти таблицы для наглядности:

tblNotes:
	.dw		19111		; C2
	.dw		18039		; C#2
	.dw		17026		; D2
	.dw		16071		; D#2
	.dw		15169		; E2
	.dw		14317		; F2
	.dw		13514		; F#2
	.dw		12755		; G2
	.dw		12039		; G#2
	.dw		11364		; A2
	.dw		10726		; A#2
	.dw		10124		; B2
	.dw		9556 		; C3
	.dw		9019 		; C#3
	.dw		8513 		; D3
	.dw		8035 		; D#3
	.dw		7584 		; E3
	.dw		7159 		; F3
	.dw		6757 		; F#3
	.dw		6378 		; G3
	.dw		6020 		; G#3
	.dw		5682 		; A3
	.dw		5363 		; A#3
	.dw		5062 		; B3
	.dw		4778 		; C4
	.dw		4510 		; C#4
	.dw		4257 		; D4
	.dw		4018 		; D#4
	.dw		3792 		; E4
	.dw		3579 		; F4
	.dw		3378 		; F#4
	.dw		3189 		; G4
	.dw		3010 		; G#4
	.dw		2841 		; A4
	.dw		2681 		; A#4
	.dw		2531 		; B4
	.dw		2389 		; C5
	.dw		2255 		; C#5
	.dw		2128 		; D5
	.dw		2009 		; D#5
	.dw		1896 		; E5
	.dw		1790 		; F5
	.dw		1689 		; F#5
	.dw		1594 		; G5
	.dw		1505 		; G#5
	.dw		1420 		; A5
	.dw		1341 		; A#5
	.dw		1265 		; B5
	.dw		1194 		; C6
	.dw		1127 		; C#6
	.dw		1064 		; D6
	.dw		1004 		; D#6
	.dw		948  		; E6
	.dw		895  		; F6
	.dw		845  		; F#6
	.dw		797  		; G6
	.dw		752  		; G#6
	.dw		710  		; A6
	.dw		670  		; A#6
	.dw		633  		; B6
	.dw		597			; C7

scanCodes:
	.db 0x1A, 0x1B	; Z, S
	.db 0x22, 0x23	; X, D
	.db 0x21, 0x2A	; C, V
	.db 0x34, 0x32	; G, B
	.db 0x33, 0x31	; H, N
	.db 0x3B, 0x3A	; J, M
	.db 0x41, 0x4B	; <, L
	.db 0x49, 0x4C	; >, :
	.db 0x4A, 0x15	; ?, Q
	.db 0x1E, 0x1D	; 2, W
	.db 0x26, 0x24	; 3, E
	.db 0x25, 0x2D	; 4, R
	.db 0x2C, 0x36	; T, 6
	.db 0x35, 0x3D	; Y, 7
	.db 0x3C, 0x43	; U, I
	.db 0x46, 0x44	; 9, O
	.db 0x45, 0x4D	; 0, P
	.db 0x4E, 0x54	; -, [
	.db 0x5B, 0x00	; ]

Получается следующее отображение клавиш фортепиано на клавиатуру:

Итого: 3 октавы + клавиша «ДО» четвёртой, всего 37 клавиш.

Полный код программы

С комментариями на английском: ATtiny2313XBoard_KeyboardOrgan.asm
Весь код после компиляции занимает 650 байт памяти кристалла.

Результат

Демонстрация^[4] полученного электронного органа:

Примечания

Использованные материалы

1. http://www.beyondlogic.org/keyboard/keybrd.htm
2. http://en.wikipedia.org/wiki/Parity_bit

Следует сразу сказать: всё, что описано в этой статье, плоды моего личного опыта, так что приведённые рецепты и рекомендации могут подходить не всем.

На всякий случай напомню, что осознанное сновидение (ОС) — это когда во сне понимаешь (осознаёшь), что находишься в сновидении и имеешь возможность сознательно действовать и изменять его содержание.

Зачем это нужно? Для начала, это просто дико интересно. Есть возможность познакомиться непосредственно со своими друзьями из подсознания (или бессознательного). Во-вторых, это даёт возможность получить дополнительные яркие ощущения. В-третьих, можно попробовать воспользоваться своим творческим аппаратом и вытащить из недр подсознания какую-нибудь информацию.

Как и любой навык, осознанное сновидение даётся отнюдь не сразу. Можно сравнить это с таким навыком, как ходьба, и на деле так оно и есть — попадая в ОС сновидящий сначала учится перемещаться по пространству сновидения и «удерживаться на ногах» — то есть не впадать в обыкновенное состояние сна или просыпаться.

Можно сказать, что мой интерес к сновидениям весьма активно подогревает как раз возможность попадать в ОС. Я открыл для себя технику, которая позволяет входить в ОС практически каждую ночь. Теперь я поделюсь ей с вами, параллельно описывая свои мысли по поводу того, как она на самом деле работает. Разумеется, всё это основано на моих личных наблюдениях, догадках и домыслах.

Итак, существует несколько условий, чтобы выйти в ОС.

1. Большое желание это сделать
2. Циклы сна по 8 часов, на протяжении достаточного времени (2-3 дня)
3. Ведение дневников снов

Вести дневник снов помогает развить навык, необходимый в осознанном сновидении. Дело в том, что «на той стороне» наш запас средств наблюдения и анализа очень сильно ограничен, как и доступ к памяти. Регулярно записывая свои сны мы нацеливаем себя на запоминание сновидений, а значит организм своеобразно настраивает всё больше и больше инструментов доступа к способностям наблюдать и запоминать сны.

Теперь техника.

1. Спать 6 часов из 8, по будильнику пробудиться и встать^[1];
2. Далее нужно не спать порядка 15-30 минут, желательно некоторое время активно двигаться;
3. Почувствовав желание не ложиться спать, сделать противоположное, то есть лечь обратно;
4. Упрямо лежать до тех пор пока не заснёшь, не забывая о намерении увидеть ОС.

Техника эта описана как очень эффективная у многих онейронавтов, похожий подход описан и у Лабержа. Но помимо знания процедуры нужно также понимать, что именно происходит в это время в организме.

Сперва давайте рассмотрим в первом приближении процесс засыпания в начале ночи (см. диаграмму 1 ниже):

Из наблюдений за собой я могу сделать вывод, что отключение отделов мозга сопровождается характерными изменениями мыслепотока. Кроме того, я начинаю зевать, причем с определённой регулярностью. В конечном итоге мыслепоток прекращается и наступает состояние сна, которое я сумел засечь только однажды в жизни, в этот момент произнося что-то вслух^[2].

В чем же эффективность техники? Дело в том, что описанный процесс засыпания характерен именно для начала ночи. То есть при пробуждении утром после 6 часов сна стадии отключения отделов мозга после их включения при повторном засыпании могут и не пройти заново! Фактически это означает что из бодрствующего состояния ты попадаешь прямо в сновидение. Однако если при засыпании начинается зевота, то наверняка стадии отключения нужных в ОС отделов мозга пошли по своему пути и вероятность ОС резко падает чуть ли не до нуля. А значит это, что организм не достаточно отдохнул и стоит попробовать в другой раз.

Процесс пробуждения показан на диаграмме 2 выше. Нам важно, чтобы нужные отделы мозга включились, иначе вместо ОС будет обычное сновидение. Именно для этого и рекомендуется встать и сделать вид, что хочешь окончательно отойти ото сна для дневной деятельности. Это соответствующим образом настраивает организм и в прямом смысле слова включает мозг.

Итак, допустим всё проделано правильно… я шёл с другом в центре города. Внезапно моё внимание привлекли яркие вечерние облака. Внезапно они превратились в огромное анимированное чудище… довольно интересная картина, но… «да я ведь сплю!»

Эта мысль, впервые «озвученная» во сне обычно приводит:

1. К пробуждению (так как нервная система реагирует на подобные заявления весьма бурно)
2. К так называемому ложному пробуждению, характерному для тех онейронавтов, кто уже познакомился с первым пунктом.

Организм, видимо, не очень-то хочет просто так засыпать-просыпаться и оптимизирует свои действия так, что пудрит мозги незадачливому онейрнонавту, сперва показывая ему его собственное пробуждение (обычно не скупясь на абсолютно достоверные детали и ощущения), а потом по-немногу увлекая в мир грёз, удаляя осознанность восвояси.

Позже я разработал тактику: в бодрствующем состоянии я четко внушил себе проверку на сон. Больше «ложные пробуждения» для меня не помеха. Пробуждаясь во сне я всегда проверяю, на самом деле я проснулся или нет. С тех пор, впрочем, все мои ОС начинаются с ложного пробуждения, то есть пунктом отправления является место, где я заснул.

Поговорим теперь о некоторых особенностях ОС.

Во-первых, возможно вас огорчит тот факт, что ОС длится в среднем не больше минуты. По крайней мере на первых стадиях освоения. Этого, к сожалению, хватает не на многое, поэтому быстро научиться ходить по миру своих сновидений вряд ли получится. Связано подобное ограничение с тем, что хотя отделы мозга и не отключились непосредственно перед засыпанием, но они будут очень рады накрыться в состоянии сна. Так что чем быстрее вы сообразите, что спите, очнувшись в сновидении, тем лучше. Со временем и опытом длительность ОС должна увеличиться.

Во-вторых, вы будете поражены, насколько реальными являются ощущения в ОС. Всё кажется настоящим: тактильные ощущения, зрительные картины, звуки, даже вкусовые рецепторы будут изображать нормальную деятельность. Вы наверняка будете любоваться картинами, построенными вашим подсознанием.

В-третьих, вам придётся постоянно контролировать стабильность ОС^[3]. Чуть что — и вы улетите оттуда как пробка из бутылки, так как мозг не очень любит, когда в сновидения нагло вторгается сознание. Он будет всячески портить вам малину^[4], банально выключая «зрение» или «слух», а то и всё вместе. Мне доводилось шастать по ОС с ограниченным полем зрения до приблизительно 1% от нормального, причем всё что я хотел сделать — это покинуть комнату, где находился (точку отправки). Раз за разом мозг возвращал меня в исходное положение.

Ну и в четвертых, даже без вмешательства «охранника», просто так свободно лазать по ОС вам никто не даст, поскольку доступ к памяти сильно ограничен. По этой причине перед тем, как лечь спать в начале ночи нужно хорошо продумать, что же вы на самом деле хотите получить в ОС.

Как и в любом другом деле, для освоение ОС вам понадобится для начала лишь сильное желание. Удачных полётов в мир сновидений!

До этого английские ребята выпустили 3 альбома, Effloresce (2003), Everyone Into Position (2005) и Frames (2007).

Что музыка? В основном, это атмосферный, «эмоциональный» прогрессив-рок. То есть виртуозных гитарных/клавишных соло и оперного вокала вы здесь не услышите. Это компенсируется оригинальностью построения мелодических линий и композиций в целом. Тяжелые части перемежаются с мягкими гитарными переборами, создавая хороший контраст.

Однако вот в силу структуры композиций и отсутствия ярко выраженного мелодического сюжета музыка Oceansize запоминается с трудом, за некоторым, конечно, исключением. Это касается первой половины творчества группы. Вторая половина — то есть альбомы Frames и Self Preserved While the Bodies Float Up — намного более интересны, полны музыкального разнообразия. Хотя кто-нибудь может сказать, что Frames слегка затянут.

Возвращаясь к их последнему альбому можно смело заявить, что это самая зрелая работа Oceansize. Боюсь, правда, что несмотря на это, этот альбом едва ли найдёт огромное число поклонников. Хотя кто знает? Для меня, например, это определённо лучший выпуск 2010 года.

Под катом две композиции для ознакомления и официальное видео для вещи SuperImposer с последнего альбома.

Oceansize — Frames (2007) — Trail of Fire

Oceansize — Self Preserved While The Bodies Float Up (2010) — Build us a rocket then…

P.S. На ютубе можно найти концертное исполнение этой вещи, где фронтмен Майк Веннарт говорит её полное на тот момент название Build us a rocket then you rocket building cunt

Официальное видео для вещи SuperImposer с того же альбома:

Дополнительно: профиль на ProgArchives.com

Если вы используете Firefox, то исправить это недоразумение можно, поставив Greasemonkey и следом скрипт в одну строчку kill_imdbcom_trivia_link.user.js.

Дизайнеру на заметку. Не надо делать пёстрый текст. Это бесит. Если уж надо поставить ссылку на каждый отдельный элемент в списке, либо ставь яваскрипт и включай ссылку при наведении на элемент, либо убери её вправо и сделай низкоконтрастной, чтобы глаза без толку не теребила.

А дело тут вот в чем. Прилетающих к нам на балкон время от времени синиц мы кормим семечками подсолнуха. Синицы забирают по семечку и улетают его очищать на куст сирени возле подъезда (в отличие от воробьев, которые жадно пожирают всё прямо на месте). Скорее всего, птица уронила какое-то из семян и оно проросло.

Более подробно остановимся на следующем:

• Музыкальная теория, необходимая для реализации музыкального проигрывателя;
• Генератор частоты на 16-ти разрядных ШИМ-каналах;
• Конвертация мелодии и удобная запись нот.

Поговорим немного и о работе с оперативной памятью SRAM и организацию работы программы по принципу обработки событий.

Введение

Когда я только начинал разбираться с микроконтроллерами семейства AVR, я собрал крохотное устройство, где в качестве генератора звука использовался tiny13. Для этого там применялась ШИМ-модуляция гармонических колебаний. Тогда мне казалось, что существенным упущением было генерировать частоту из основного цикла без использования прерываний. Однако позже выяснилось, что модуляция синуса, даже с разрешением 8 бит и даже при наличии таблицы синусов для проигрывания мелодии задача весьма нетривиальная и крайне критичная по времени. В случае ATtiny2313 в наличии всего два таймера, а требуется контролировать ШИМ, модуляцию синуса на двух каналах, длительность нот, а также общий ход программы при сохранении многозадачности.

В итоге я решил, что буду рисовать музыку прямоугольными колебаниями^[1]. Вообще моей главной задачей было получить как можно более точную частоту, элегантный способ задания высоты и длительности нот. И, как мне кажется, это было достигнуто.

Схема устройства

Схема (PDF): ATtiny2313_music_player

Для генерации сигнала будем использовать 16-битный таймер, поэтому нам нужны выводы микроконтроллера OC1A и OC1B. С них будем брать левый и правый каналы, предварительно пропустив через RC-фильтр, у которого две основных функции:

• Работа в режиме интегратора — из ШИМ получается сигнал заданного уровня;
• Работа в режиме фильтра нижних частот.

Первая функция в данном проекте практически никакого применения не находит, а вот фильтр нужен для удаления из генерируемого сигнала паразитных высокочастотных составляющих, в том числе нежелательных обертонов. Частоту среза в герцах можно посчитать при помощи уравнения:

В данном случае я использовал значения R=470Ω, C=100nF. Это даёт частоту среза 3386.27 Гц, что вполне подходит для проигрывателя.

Насчёт подключения акустической системы: я включал напрямую к маломощному динамику на 8Ω, сил микроконтроллера хватало на достаточно громкое воспроизведения музыки. Причём я сводил два канала в один, просто соединяя два провода вместе. Вообще так делать не рекомендуется, весьма желательно воткнуть между выходом с микроконтроллера и акустической системой операционный усилитель-другой.

Немного теории

Нашей задачей является создание проигрывателя, значит, нужно вспомнить азы музыкальной теории. Композиции состоят из совокупности нот, а у всякой ноты имеется два фундаментальных параметра — высота и длительность.

Высота ноты

Высота ноты задаётся определённой частотой колебаний звукового сигнала. Для расчета периода колебаний по частоте нам будет нужна простейшая формула. К ней мы вернёмся немного позже:

В современной музыке ныне практически повсеместно используется так называемый равномерно темперированный строй. Вдаваться в подробности я не буду, если интересно, к вашим услугам статья на Википедии. Нам для проекта необходимо знать соответствие высот нот частотам согласно этому строю. На той же Википедии есть вполне годная таблица, которой мы и воспользуемся.

Длительность ноты

В музыке длительность ноты понятие относительное и зависит от темпа, в котором исполняется произведение. Темп обычно задаётся в ударах в минуту (bpm), причём один удар равен одной четвертной ноте. Следовательно, запись 100 bpm (или =100) означает, что в минуте помещается ровно 100 четвертных нот. Нетрудно тогда посчитать и длительность одной четвертной ноты, 1/100 = 0.01 минут или 0.6 секунд^[2].

Посчитаем для примера реальные длительности нот для темпа =120. Основой будет длительность четвертной ноты, равной в этом случае 60000/120=500 мс.

Обозначение	Отношение	Длительность (мс)
	4/4 (целая)	2000
	2/4 (половинная)	1000
	1/4 (четвертная)	500
	1/8 (восьмая)	250
	1/16 (шестнадцатая)	125
	1/32 (тридцатьвторая)	62.5

Планировка программы

Опираясь на приведённую выше информацию, а также на технические возможности ATtiny2313, можно составить общий план работы программы.

Генерация заданной частоты

Нам нужен прямоугольный сигнал с частотой, соответствующей определённой ноте. Прямоугольник можно получить, чередуя выходные сигналы микроконтроллера 0→1→0→…, причём время стабильного состояния низкого и высокого уровней должно быть одинаковым. Оно будет тогда являться не чем иным, как полупериодом колебания. Следовательно, два раза по столько и получим полный период, откуда можно высчитать и частоту. Таким образом, частоту будем задавать через полупериод колебания.

Для генерации сигнала мы используем 16-битный таймер. Из даташита определим подходящий режим его работы. Это будет нормальный режим, с таким приколом: таймер считает от 0 до 65535, а при достижении значения OCR1A (OCR1B) чередует на соответствующем выводе уровень сигнала (0→1 или 1→0).

Этого, конечно, маловато будет. Ведь если таймер перекинул выход, он затем будет считать ещё 65535 тиков до следующего изменения, как тогда задать полупериод? С одной стороны логично предложить сброс таймера при достижении OCR1A. Но второй канал тогда определённо сильно пострадает.

Можно поступить следующим образом. Включим прерывания по достижении значений OCR1A и OCR1B. В обработчике такого прерывания будет код, прибавляющий к текущему значению регистра аккурат ровно столько же тиков, сколько нужно для задания полупериода. То есть, например, полупериод задан 2300 тиками таймера, текущее значение на момент прерывания было 4100. Тогда следующее прерывание должно произойти в момент времени 2300+4100=6400. Это значение и занесём в регистр. Вот и готов наш генератор прямоугольной частоты.

Давайте теперь рассмотрим конкретные цифры. Согласно нашей рабочей схеме, ATtiny2313 работает от кристалла с частотой 20.000 МГц. Тогда если взять предделитель /8 таймера1, получим, что длительность одного тика таймера равна:

Иными словами, мы можем задавать длительность полупериода с разрешением в 0.4 микросекунд. Выведем формулу для определения количества тиков таймера из исходной частоты:

Число тиков для, скажем, частоты 440.000 Гц (соответствует ноте ля 4-ой октавы — A4) определяется так:

Конечно, мы рассматриваем целочисленные значения, так как десятичные дроби таймеру не скормишь. Из-за округления возникает некоторая ошибка при формировании частоты. Но как показывает практика, эта ошибка находится в допустимом диапазоне.

Для того, чтобы изменения сигналов были поданы на вывод микроконтроллера, соответствующие порты должны быть заданы как выходные в регистре DDR. Это пригодится для пауз на каналах: мы просто будем отключать выход и получать с него тишину.

Выдержка длительности нот

Поскольку у нас остался один восьмибитный таймер, то для задания времени звучания нот на каждом из каналов понадобятся софт-таймеры (то есть полученные программно). «Железный» же таймер заставим работать как генератор прерываний; в обработчик прерывания засунем код, который будет поддерживать правильную работу системы и следить за софт-таймерами.

Возьмём режим работы таймера0: сброс при достижении OCR0A. В качестве предделителя используем /64. Будем генерировать прерывания каждые 50 тиков, следовательно в регистр OCR0A требуется занести значение 49. При таком подходе каждое такое прерывание назовём тиком системных часов. Время одного тика:

Получаем разрешение для софт-таймеров в 0.16 мс. Этого хватит и для достаточно высокого темпа воспроизведения.

Софт-таймеры длительности нот организуем таким образом, чтобы они считали в обратную сторону. Оттикав заданное число, раз они инициируют смену ноты. Число тиков этих таймеров зависит от реальной длительности ноты следующим образом:

где t_note — длительность ноты в миллисекундах. Так, например, для длительности восьмой ноты в темпе =120 количество тиков будет равно:

Обратно же, в наличии некоторая погрешность, но куда без неё? :-)

Управление ходом программы

Сделаем так, что при нажатии одной кнопки начинается воспроизведение. При этом загорается светодиод. Программа сбрасывается в двух случаях (при этом светодиод гаснет):

1. Вся мелодия сыграна;
2. Нажата вторая кнопка.

Управление будем осуществлять из главного цикла программы.

Программный код

Ну вот мы и подошли, похоже, к самой интересной части статьи. Рассматривать код будем по кусочкам.

Определения символьных имён

Сперва, конечно, в листинг нужно кинуть инклуд с именем зверя, а также назначить символьные имена регистров, используемых в программе. Констант у нас пока не будет, обойдёмся без них.

 ; Проект для ATtiny2313
.INCLUDE "tn2313def.inc"

; ---------------------
; Определения регистров
; ---------------------

.DEF	SrSave	= R9		; Хранение регистра состояния

.DEF	Tone1H	= R10		; Старший байт тона канала 1
.DEF	Tone1L	= R11		; Младший байт тона канала 1
.DEF	Tone2H	= R12		; Старший байт тона канала 2
.DEF	Tone2L	= R13		; Младший байт тона канала 2

.DEF	ToneTH	= R14		; Старший байт тона
.DEF	ToneTL	= R15		; Младший байт тона

.DEF	Temp	= R17		; Временный регистр

.DEF	Temp1 	= R18		; Вспомогательные регистры
.DEF	Temp2	= R19
.DEF	Temp3	= R20
.DEF 	Temp4	= R21

.DEF	ADDRH	= R22		; Старший байт адреса
.DEF 	ADDRL	= R23		; Младший байт адреса

Регистры R10—R13 используются для хранения тона на протяжении всей длительности ноты для генерации частоты (можно использовать SRAM, но тут нам важна скорость отработки прерываний, так что лучше будет хранить данные в регистрах). R16 же я не использовал, потому что он активно задействован в макросах.

Макросы

Я использовал всего четыре макроса. Вот они:

 ; --------------------
; Определения макросов
; --------------------

; OUTI port, value :: отправить значение в порт
.MACRO OUTI
	ldi R16,@1
	out @0,R16
.ENDM

; MEMR register, (location) :: считать из памяти в регистр
.MACRO MEMR
	lds @0, @1
.ENDM

; MEMW (location), register :: записать в память регистр
.MACRO MEMW
	sts @0, @1
.ENDM

; MEMWI (location), value :: записать значение в память
.MACRO MEMWI
	ldi R16, @1
	sts @0, R16
.ENDM

Из них реально полезными являются OUTI и MEMWI, два других, MEMR и MEMW, просто псевдонимы соответственно инструкций lds и sts, введённые исключительно для моего удобства.

Разметка SRAM

Для использования оперативной памяти в программах можно предварительно разметить необходимую область памяти под свои нужды. Делается это при помощи директивы .DSEG, последующих меток и соответствующих меткам директив .BYTE, «выделяющих» в памяти необходимое количество байт^[3].

Для нашей программы зарезервируем всего 8 байт. В первых четырех будут хранится текущие адреса таблицы нот для первого и второго каналов. Остальные байты пойдут под 16-ти разрядные софт-таймеры.

Получаем такую структуру:

 ; -------------
; Разметка SRAM
; -------------

.DSEG

; Позиция первой мелодии
melody1:
	.BYTE 2

; Позиция второй мелодии
melody2:
	.BYTE 2

; Текущие длительности нот
duration1:
	.BYTE 2

duration2:
	.BYTE 2

Таблица прерываний

Согласно плану программы, нам нужно определить обработчики для трёх прерываний. Не стоит забывать также и о директивах .CSEG и .ORG 0x0000, означающих начало кода программы с адреса 0x0000.

 ; ---------------------
; Начало кода программы
; ---------------------

.CSEG
.ORG 0x0000

; ------------------
; Таблица прерываний
; ------------------

rjmp Init ; Обработчик сброса
reti
reti
reti
rjmp TIMER1_COMPA ; Обработчик CompareA таймера1
reti
reti
reti
reti
reti
reti
reti
rjmp TIMER1_COMPB ; Обработчик CompareB таймера1
rjmp TIMER0_COMPA ; Обработчик CompareA таймера0
reti
reti
reti
reti
reti

Остальные прерывания у нас не используются, и на них стоит заглушка в виде инструкции reti.

Инициализация и основной цикл

 ; -------------------------
; Начало основной программы
; -------------------------

Init:

	; Ждать, пока не нажата кнопка1
	cbi DDRD, 4
	sbi PORTD,4

waitkey:

	sbic PIND, 4
	rjmp waitkey

	; Задать выходы
	; (изначально отключить вывод прямоугольных колебаний)
	outi DDRB, (1<<PB0) | (0<<PB3) | (0<<PB4)

	; Задать стек
	outi SPL, low(RAMEND)

	; Включить светодиод
	sbi PORTB, 0

	; Инициализировать железо
	rcall Timer1_Init
	rcall TIMER_Init

	; Установить прерывания
	outi TIMSK, (1<<OCIE1A) | (1<<OCIE1B) | (1<<OCIE0A)

	; Записать изначальные локации мелодий в память

	; 1 канал
	memwi melody1, high(tblMelody1*2)
	memwi melody1+1, low(tblMelody1*2)

	; 2 канал
	memwi melody2, high(tblMelody2*2)
	memwi melody2+1, low(tblMelody2*2)

	; Очистить регистры сравнения
	outi OCR1AH, 0
	outi OCR1AL, 0

	outi OCR1BH, 0
	outi OCR1BL, 0

	; Установить ноты
	rcall setCh1
	rcall setCh2

	; Очистить таймер0
	outi TCNT0, 0

	; Очистить таймер1
	outi TCNT1H, 0
	outi TCNT1L, 0

	; Сбросить предделитель
	outi GTCCR, (1<<PSR10)

	; Включить прерывания и начать игру
	sei

back2:

	; Сброс, если кнопка2 нажата
	sbi PORTD,5

	sbis PIND, 5
	rjmp endplay

	rjmp back2

Обратите внимание, что стек нужно задать в явном виде. Поскольку на борту tiny2313 всего 128 байт оперативной памяти, то старшего байта у регистра стека нет.

Основной цикл программы в петле с возвращением в метку back2. Здесь проверяется нажатие второй кнопки, всё остальное организовано в обработчике системных часов.

Инициализация железа

Тут нужно просто задать параметры для двух таймеров.

 ; ----------------------
; Инициализация железа
; ----------------------

; Инициализация таймера1
Timer1_Init:

	; Включить смену уровней при сравнении
	outi TCCR1A, (1<<COM1A0) | (1<<COM1B0) | (0<<WGM10)

	; Включить таймер с предделителем /8
	outi TCCR1B, (2<<CS10)

	ret

; Инициализация таймера0 (системного таймера)
TIMER_Init:

	; Установить режим работы
	outi TCCR0A, (1<<WGM01) | (0<<WGM00)

	; Установить значение переполнения
	outi OCR0A, 49

	; Установить предделитель /64
	outi TCCR0B, 3

	ret

Завершение программы

Как было сказано, завершение^[4] происходит в случае окончания проигрывания мелодии или нажатия кнопки 2.

 ; ---------------------
; Конец воспроизведения
; ---------------------

ENDPLAY:

	; Игра завершена или прервана
	cli

	; Очистить порты
	clr R16
	out PORTB, R16

	; Отменить воспроизведение на обоих каналах
	cbi DDRB, 3
	cbi DDRB, 4

	; Очистить флаги прерываний
	outi TIFR, (1<<OCF1A) | (1<<OCF1B) | (1<<OCF0A)

	rjmp Init

Установка ноты на канале

Рассмотрим код для установки ноты на канале. Всего у нас будет четыре таблицы данных, которые мы разместим во флеш-памяти, поскольку в EEPROM они целиком всё равно не влезут (да и скорость доступа оттуда низкая). Таблицы будут такими:

• Таблица нот
• Таблица длительностей
• Таблица мелодии на канале 1
• Таблица мелодии на канале 2

Все значения в таблицах будут кодироваться словами (2 байта). В случае нот мы кодируем высоту и длительность, а мелодии состоят из пар байт нота-длительность (плюс управляющие слова). Не обязательно заносить в таблицы нот и длительности все ноты подряд, достаточно лишь тех, что используются в конкретном произведении. Это позволяет сэкономить место.

Рассмотрим код для первого канала (код для второго канала отличается именами используемых регистров и адресов памяти, в остальном идентичен).

 ; -----------------------------------------
; Функции по управлению тона и длительности
; -----------------------------------------

; ------------------
; Установка канала 1
; ------------------
setCh1:

	; Загрузить ноту и длительность
	memr ZH, melody1
	memr ZL, melody1+1

	; Взять байт ноты
	lpm
	mov Temp1, R0

	; Взять байт длительности
	adiw zl, 1
	lpm
	mov Temp2, R0

	; Сохранить адрес следующей ноты
	adiw ZL, 1
	memw melody1, ZH
	memw melody1+1, ZL

	; Проверка на управляющий байт конца
	cpi Temp1, 255
	breq endplay

	; Проверка на паузу
	cpi Temp1, 0
	breq isPause1

	dec Temp1

	ldi ADDRH, high(tblNotes*2)
	ldi ADDRL, low(tblNotes*2)
	rcall getVals

	; Получить значение тона
	mov Tone1H, Temp3
	mov Tone1L, Temp4

	in ToneTH, OCR1AH
	in ToneTL, OCR1AL

	add ToneTL, Tone1L
	adc ToneTH, Tone1H

	out OCR1AH, ToneTH
	out OCR1AL, ToneTL

	; Включить вывод сигнала на первом канале
	sbi DDRB, 3

	rjmp noPause1

isPause1:

	; Пауза — отключить вывод сигнала на первом канале
	cbi DDRB, 3

noPause1:

	; Загрузить длительность
	ldi ADDRH, high(tblDuration*2)
	ldi ADDRL, low(tblDuration*2)
	mov Temp1, Temp2
	rcall getVals

	memw duration1, Temp3
	memw duration1+1, Temp4

	; Выход из процедуры
	ret

endplay1:
	rjmp endplay

В коде используется вызов процедуры getVals. Она просто считывает данные из указанного адреса флеш-памяти и заносит в регистры Temp3 и Temp4:

 ; --------------------------------------
; Загрузить значения из памяти программы
; --------------------------------------

getVals:

	mov ZH, ADDRH
	mov ZL, ADDRL

	lsl Temp1

	clr R16
	add ZL, Temp1
	adc ZH, R16

	lpm
	mov Temp4, R0

	adiw ZL, 1
	lpm
	mov Temp3, R0

	ret

Кроме того, есть переход — rjmp endplay, он здесь потому, что дальше программе было не достать метку endplay (из-за ограниченности длины прыжка, максимально равной 127 байт) и пришлось использовать вспомогательный переход.

Генератор частоты

Рассмотрим первый канал:

 ; --------------------------
; Управления тоном канала 1
; --------------------------

TIMER1_COMPA:

	; Отключить прерывания
	cli

	; Сохранить SREG
	in SrSave, SREG

	; Задать следующий полупериод
	in ToneTH, OCR1AH
	in ToneTL, OCR1AL
	add ToneTL, Tone1L
	adc ToneTH, Tone1H
	out OCR1AH, ToneTH
	out OCR1AL, ToneTL

	; Восстановить SREG
	out SREG, SrSave

	; Включить прерывания
	sei

	reti

Всё согласно рассуждениям выше. Кроме того:

• Чтобы не произошло произвольной фигни, нужно отключать прерывания
• Также, поскольку контроль тона может происходит часто, прерывания могут возникнуть где угодно в программе и грохнуть SREG, что опять же приведёт к рандомной фигне, так что его надо сохранять и восстанавливать

Всё вышесказанное справедливо и для второго канала.

Обработчик системных часов

Тот самый, который тикает раз в 160 микросекунд. Вот код:

 ; --------------------------
; Главный обработчик событий
; --------------------------

TIMER0_COMPA:

	; Проверить длительность на 1 канале
	memr Temp3, duration1
	memr Temp4, duration1+1

	clr R16
	subi Temp4, 1
	sbc Temp3, R16
	brcc saveDur1

	; Загрузить следующую ноту
	cli
	rcall setCh1
	sei

	rjmp nextDur

saveDur1:

	memw duration1, Temp3
	memw duration1+1, Temp4

nextDur:

	memr Temp3, duration2
	memr Temp4, duration2+1

	clr R16
	subi Temp4, 1
	sbc Temp3, R16
	brcc saveDur2

	cli
	rcall setCh2
	sei

	rjmp next1

saveDur2:

	memw duration2, Temp3
	memw duration2+1, Temp4

next1:

	reti

На этом программный код готов. Теперь нужна какая-нибудь музыка, которую наш проигрыватель будет играть.

Музыкальная композиция

Lilium.mid

В качестве мелодии для проигрывателя я выбрал весьма красивую титульную тему Lilium из аниме Elfen Lied.

У нас двухканальный (двухголосый) синтезатор, значит нам нужно расписать композицию на два голоса, что я и сделал. Использовал я для этого MIDI-файл.

Как перекладывать музыку вариантов может быть несколько. Тут нам нужен какой-нибудь MIDI-редактор, способный показывать ноты во вменяемом виде^[5]. Очень удобно использовать режим просмотра piano roll (пример в Nuendo 3), так как тут наглядно видно и ноты, и их длительности.

Преобразование к формату проигрывателя

Конвертацию делать придётся вручную (автоматические средства пока не доступны): выписываем каждую ноту ровно один раз и подбираем для неё число тиков по приведённой выше формуле. Смотрим, первая нота F#4. Посмотрим по таблице частоту этой ноты. Увидим значение 369.994. Значит, число тиков будет

Выпишем в таком духе все ноты, участвующие в произведении, и посчитаем для них число тиков таймера. Удобно для расчётов использовать Microsoft Excel или какой-нибудь математический пакет вроде Scilab или Maxima. Я, например, заготовил таблицу (Excel 2003) и PDF файл.

Затем пройдёмся по композиции ещё раз и выпишем все участвующие в нём длительности. Вычислим и для них соответствующее число тиков софт-таймера, учитывая темп произведения =60, что значит, что длительность четвертной ноты равна 1 секунде. Не забываем также и о паузах.

Когда всё это готово, запишем в ассемблерный листинг таблицы с полученными нотами и длительностями.

Таблицы нот и длительностей в ассемблере

Таблица будет состоять из слов (в данном случае размером два байта), значит нужно воспользоваться директивой .DW. Составим таблицу нот:

 ; --------------
; Таблицы данных
; --------------

; Таблица нот :: тон = 1/(8e-7*N)
tblNotes:
	.dw 11364	; A2
	.dw 10124	; B2
	.dw 9556	; C3
	.dw 9019	; C#3
	.dw 8513	; D3
	.dw 7584	; E3
	.dw 7159	; F3
	.dw 6757	; F#3
	.dw 6020	; G#3
	.dw 5682	; A3
	.dw 5363	; A#3
	.dw 5062	; B3
	.dw 4510	; C#4
	.dw 4257	; D4
	.dw 4018	; D#4
	.dw 3792	; E4
	.dw 3579	; F4
	.dw 3378	; F#4
	.dw 3010	; G#4
	.dw 2841	; A4
	.dw 2681	; A#4
	.dw 2531	; B4
	.dw 2389	; C5
	.dw 2255	; C#5
	.dw 2128	; D5
	.dw 1896	; E5
	.dw 1689	; F#5

Воспользуемся на этом этапе константами. Это очень удобное средство сопоставить положение ноты в таблице конкретному символьному имени, которое можно будет использовать при записи мелодии. Константы вводятся в эксплуатацию директивой .EQU.

 ; Зададим символьные имена нот

; Они отмечают реальные позиции
; нот в tblNotes

; Специальные значения: PAUSE = 0, END = 255

	.equ 	PAUSE	=	0
	.equ 	A2		=	1
	.equ 	B2		=	2
	.equ 	C3		=	3
	.equ 	Cs3		=	4
	.equ 	D3		=	5
	.equ 	E3		=	6
	.equ 	F3		=	7
	.equ 	Fs3		=	8
	.equ 	Gs3		=	9
	.equ 	A3		=	10
	.equ 	As3		=	11
	.equ 	B3		=	12
	.equ 	Cs4		=	13
	.equ 	D4		=	14
	.equ 	Ds4		=	15
	.equ 	E4		=	16
	.equ 	F4		=	17
	.equ 	Fs4		=	18
	.equ 	Gs4		=	19
	.equ 	A4		=	20
	.equ 	As4		=	21
	.equ 	B4		=	22
	.equ 	C5		=	23
	.equ 	Cs5		=	24
	.equ 	D5		=	25
	.equ 	E5		=	26
	.equ 	Fs5		=	27
	.equ	END		=	255

Сделаем то же самое и для таблицы длительностей:

 ; Таблица длительностей :: bpm=60
; Tim0 /64, 50тиков -> 1.6e-4 секунд на CMP эвент

tblDuration:
	.dw 25000	; полная нота
	.dw 18750	; 1/2 с точкой
	.dw 12500	; 1/2
	.dw 6250	; 1/4
	.dw 3125	; 1/8

; Символьные имена длительностей

	.equ d1		= 0
	.equ d12dot	= 1
	.equ d12	= 2
	.equ d14	= 3
	.equ d18	= 4

Обратите внимание, что тут я использовал обозначение целой ноты как d1, а половинной — d12, хотя корректнее было бы использовать d44 и d24. Однако мне так было удобнее.

Запись композиции

Когда всё это сделано, можно начинать записывать саму композицию, в два прохода — сначала один канал, а затем второй. Вот что получилось:

 ; Канал первой мелодии
tblMelody1:
	.db Fs4, d18	; Часть 1
	.db Cs5, d18
	.db Gs4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db A4, d18
	.db A4, d18
	.db A3, d18
	.db Fs4, d18
	.db Cs5, d18
	.db Gs4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db A4, d18
	.db B4, d18
	.db A4, d18
	.db Fs4, d18
	.db A3, d18
	.db D4, d18
	.db A3, d18
	.db B3, d18
	.db Gs4, d18
	.db E4, d18
	.db D4, d18
	.db E4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db Gs3, d18
	.db As3, d18
	.db Fs4, d18
	.db D4, d18
	.db Cs4, d18
	.db D4, d18
	.db E4, d18
	.db Fs4, d14
	.db PAUSE, d18
	.db Gs4, d18
	.db A4, d18
	.db B4, d18
	.db A4, d18
	.db Cs4, d18
	.db Fs4, d18
	.db A4, d18
	.db Gs4, d14
	.db Fs4, d18 ; Часть 2
	.db Cs5, d18
	.db Gs4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db A4, d18
	.db A4, d18
	.db A3, d18
	.db Fs4, d18
	.db Cs5, d18
	.db Gs4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db A4, d18
	.db B4, d18
	.db A4, d18
	.db Fs4, d18
	.db A3, d18
	.db D4, d18
	.db A3, d18
	.db B3, d18
	.db Gs4, d18
	.db E4, d18
	.db D4, d18
	.db E4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db Gs3, d18
	.db As3, d18
	.db Fs4, d18
	.db D4, d18
	.db Cs4, d18
	.db D4, d18
	.db B4, d18
	.db A4, d18
	.db Gs4, d18
	.db Fs4, d18
	.db F4, d18
	.db Ds4, d18
	.db F4, d18
	.db Fs4, d18
	.db As4, d18	; Часть 3
	.db B4, d18
	.db Cs5, d18
	.db D5, d18
	.db A4, d18
	.db Gs4, d18
	.db D5, d18
	.db Cs5, d18
	.db E5, d18
	.db A4, d18
	.db Cs5, d18
	.db C5, d18
	.db A4, d18
	.db Gs4, d18
	.db Fs4, d18
	.db A4, d18
	.db Cs4, d18
	.db Fs4, d18
	.db B4, d18
	.db Gs4, d12dot
	.db Fs4, d18	; Часть 4
	.db Cs5, d18
	.db Gs4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db A4, d18
	.db A4, d18
	.db A3, d18
	.db Fs4, d18
	.db Cs5, d18
	.db Gs4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db A4, d18
	.db B4, d18
	.db A4, d18
	.db Fs4, d18
	.db A3, d18
	.db D4, d18
	.db A3, d18
	.db B3, d18
	.db Gs4, d18
	.db E4, d18
	.db D4, d18
	.db E4, d18
	.db Gs3, d18
	.db Cs4, d18
	.db Gs3, d18
	.db As3, d18
	.db Fs4, d18
	.db D4, d18
	.db Cs4, d18
	.db D4, d18
	.db B4, d18
	.db A4, d18
	.db Gs4, d18
	.db Fs4, d18
	.db F4, d18
	.db Ds4, d18
	.db F4, d18
	.db Fs4, d18
	.db Cs4, d18
	.db Fs4, d18
	.db B4, d18
	.db Fs5, d12

	.db END, 0

; Канал второй мелодии
tblMelody2:
	.db PAUSE, d14
	.db F3, d12
	.db Fs3, d14
	.db A2, d18
	.db PAUSE, d18
	.db F3, d12
	.db Fs3, d14
	.db D3, d1
	.db Cs3, d12
	.db Fs3, d12
	.db B2, d12
	.db C3, d12
	.db Cs3, d12
	.db Gs3, d12
	.db F3, d12
	.db Fs3, d14
	.db A2, d18
	.db PAUSE, d18
	.db F3, d12
	.db Fs3, d14
	.db D3, d1
	.db Cs3, d12
	.db Fs3, d12
	.db B2, d14
	.db C3, d14
	.db Cs3, d14
	.db F3, d14
	.db Fs3, d12
	.db B3, d14
	.db E3, d14
	.db A3, d14
	.db Fs3, d14
	.db A3, d14
	.db C3, d14
	.db Cs3, d12
	.db Cs4, d12dot
	.db PAUSE, d14
	.db F3, d12
	.db Fs3, d14
	.db A2, d18
	.db PAUSE, d18
	.db F3, d12
	.db Fs3, d14
	.db D3, d1
	.db Cs3, d12
	.db Fs3, d12
	.db B2, d14
	.db C3, d14
	.db Cs4, d14
	.db F3, d14
	.db Fs3, d12
	.db A4, d12

	.db END, 0

Полный код программы

Вот полный код (комментарии на английском): ATtiny2313XBoard_MusicPlayer.asm

В полученной прошивке код и данные занимают где-то по 500 байт, оставляя свободным ещё 1КБ для разнообразного контента, будь то дополнительный код или музыка.

Результат

Запрограммируем контроллер, не забывая выставить фузы на работу от внешнего кристалла (CKSEL3...0 = 0). Нажмём на кнопку и из микроконтроллера начинает стремиться музыка:

Задача выполнена :-) Надеюсь, материал был для вас полезным! Через некоторое время последует вторая часть статьи, посвещенная MIDI и последовательной передаче данных в контексте того же ATtiny2313.

Успехов!

Примечания

Поскольку тема новая и пока ещё не обкатанная как следует, с ней возможны проблемы. Пожалуйста, сообщайте о них в комментариях. До сих пор были найдены некоторые проблемы с IE6.

Обновление: Все обнаруженные проблемы с IE6 решены. Подробнее здесь.